Smart Dustbin using Ultrasonic Sensor & Servo Motor

• How an ultrasonic sensor measures distance using sound waves
• How to control a servo motor to rotate to specific angles
• How to combine multiple components to create a smart automated system
• Understanding trigger and echo pins for distance measurement
• Foundation for building automation, robotics, and IoT projects

Understand the Components

HC-SR04 Ultrasonic Sensor - This sensor sends out a sound wave (similar to how bats use echolocation) and measures how long it takes to bounce back. From that time, it calculates the distance to an object.

It has 4 pins:

1. VCC → 5V on Arduino
2. GND → GND on Arduino
3. TRIG → Pin 9 (we send a signal here to start measuring)
4. ECHO → Pin 10 (we receive the bounced signal here)

SG90 Servo Motor - A small motor that can rotate to exact angles (0° to 180°). We'll use it to open and close the dustbin lid.

1. Red wire → 5V on Arduino
2. Brown/Black wire → GND on Arduino
3. Orange/Yellow wire → Pin 6 on Arduino (control signal)

Wire the Circuit

Connect both components to the Arduino:

1. Connect HC-SR04 VCC → 5V, GND → GND, TRIG → Pin 9, ECHO → Pin 10
2. Connect Servo red wire → 5V, brown wire → GND, orange wire → Pin 6
3. Attach the servo motor to the dustbin lid using tape or a small bracket

Wiring Diagram

Write the Code by opening Arduino UNO

// Smart Dustbin - NKDevSpace Tutorial
#include <Servo.h>

Servo lidServo;

const int trigPin = 9;
const int echoPin = 10;
const int servoPin = 6;

void setup() {
  pinMode(trigPin, OUTPUT);
  pinMode(echoPin, INPUT);
  lidServo.attach(servoPin);
  lidServo.write(0);   // Start with lid closed
  Serial.begin(9600);
}

long getDistance() {
  // Send ultrasonic pulse
  digitalWrite(trigPin, LOW);
  delayMicroseconds(2);
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(trigPin, LOW);

  // Measure how long echo takes to return
  long duration = pulseIn(echoPin, HIGH);

  // Convert time to distance in cm
  long distance = duration * 0.034 / 2;
  return distance;
}

void loop() {
  long distance = getDistance();

  Serial.print("Distance: ");
  Serial.print(distance);
  Serial.println(" cm");

  if (distance > 0 && distance < 20) {
    // Hand is close - open the lid
    lidServo.write(90);   // Rotate to 90 degrees (open)
    delay(3000);          // Keep open for 3 seconds
    lidServo.write(0);    // Close the lid
    delay(2000); // prevent immediate retrigger
  }

  delay(200);
}

Code Explanation

Upload & Test

1. Make sure your Arduino Uno is connected to your laptop using a USB cable
2. If not already selected, set the correct options:
   • Go to Tools → Board → Arduino AVR Boards → Arduino Uno
   • Go to Tools → Port → COM X(COM 3, COM4, ...) (Arduino Uno)
3. Click the Upload (→) button to upload the code
4. Open Tools → Serial Monitor
5. Set the baud rate to 9600
6. You will see the distance values printing continuously
7. Bring your hand within 20 cm of the sensor
8. The servo motor should rotate and open the lid
9. After 3 seconds, the lid should close automatically

Try It Yourself - Challenges

• Add an LED that glows green when the lid is open
• Add a second ultrasonic sensor to detect when the bin is full
• Add a buzzer that beeps when the bin is full
• Change the open duration from 3 seconds to 5 seconds